Extraction des données d'une référence avec Excel

Pour partager cette vidéo sur les réseaux sociaux ou sur un site, voici son url :


Sujets que vous pourriez aussi aimer :


Extraire tous les enregistrements d'une référence

Dans les formations précédentes, nous avions vu comment extraire des données purgées de leurs doublons par calculs Excel. Ici au contraire, nous souhaitons extraire tous les enregistrements correspondant à une donnée répétitive.



Une entreprise grossiste en semences agricoles souhaite extraire tous les ordres de fabrication (OF) relatifs à un numéro de lot. Nous devons donc bâtir une console permettant de sélectionner un lot identifié par son numéro. Des calculs doivent alors se déclencher pour extraire toutes les informations attachées. Ces informations peuvent se décliner sur plusieurs lignes. L'enjeu consiste donc à extraire tous les enregistrements attachés à une seule référence. Et nous le verrons, les données sont réparties dans plusieurs sources. Nous devrons donc réaliser des extractions croisées.

Source et présentation du concept
Comme nous avons besoin de données volumineuses, nous proposons de récupérer une source dans laquelle la structure de la console est déjà bâtie.

• Télécharger le classeur extraction-donnees-reference.xlsx en cliquant sur son lien,
• L'ouvrir dans Excel et cliquer sur le bouton Activer la modification du bandeau de sécurité,

Comme vous le constatez, ce classeur est constitué de trois feuilles.

• Cliquer sur l'onglet Stock en bas de la fenêtre Excel pour activer sa feuille,

Il s'agit de la base de données principale constituée d'environ 800 lignes. On y recense les numéros de lots en cours de préparation avec un identifiant précis en colonne C (N° série/ Lot). A ces lots sont associés quelques renseignements décrits par les champs Description, Quantité et Emplacement. Ces numéros peuvent présenter des redondances car bien qu'identiques, ils n'offrent pas la même quantité et sont stockés à différents emplacements.

Et surtout, pour chaque lot identifié par son numéro, nous souhaitons remonter à un niveau de détail encore plus important, afin de visualiser sur demande, les Ordres de fabrication (OF) qui leur sont attachés. Mais à l'instar des bases de données organisées par tables reliées entre elles, ces informations secondaires se trouvent dans une autre source.

• Cliquer sur l'onglet OF en bas de la fenêtre Excel pour activer sa feuille,

Cette feuille propose une nouvelle source d'environ 300 lignes, recensant ces fameux ordres de fabrication en première colonne (N° OF). Les informations listées sont assez détaillées étant donnée la quantité de champs offerte. L'un d'entre eux se nomme LOT FINAL en colonne S. Il rappelle les numéros de lots. Il permet donc d'établir le lien entre un numéro de lot et ses ordres de fabrication.

• Cliquer sur l'onglet Console en bas de la fenêtre Excel pour activer sa feuille,

C'est précisément cette souplesse d'exécution que nous souhaitons offrir au responsable depuis cette dernière feuille. Afin de simplifier le suivi et la logistique de tous ces lots, il doit pouvoir désigner l'un d'entre eux par le biais d'une liste déroulante en B5. Instantanément, toutes les informations qui lui sont attachées doivent être remontées dans les colonnes prévues à cet effet. Il va donc s'agir de réaliser des extractions mettant en jeu des interactions entre plusieurs sources de données, situées sur plusieurs feuilles.

Il s'agit de restituer la quantité en stock et l'emplacement en colonnes B et C. Les informations secondaires, issues de la deuxième feuille quant à elles, doivent être rapatriées entre les colonnes E et K. Mais souvenez-vous, un numéro de lot peut être répété et les informations attachées peuvent varier. L'enjeu consiste donc à extraire tous les enregistrements, croisés dans les deux tables et attachés à une même référence. En d'autres termes, nous souhaitons produire l'extraction de toutes les données de valeurs redondantes.

Liste de valeurs uniques
Avant de débuter ces recherches permettant d'importer les données correspondantes, nous souhaitons offrir en B5 de la feuille console, une liste déroulante des numéros de lots. Bien entendu, dans cette liste, les répétitions ne doivent pas être proposées. Nous devons commencer par restituer une source des numéros de lots dans laquelle les redondances sont éliminées.

Pour ce faire, nous devons commencer par réaliser une formule intermédiaire dans la feuille Stock, pour identifier chaque valeur unique de lot. Comme nous l'avions fait dans la formation pour purger les doublons d'une liste, nous allons ajouter un indicateur numérique incrémenté en regard de chaque nouveau numéro de lot. Ce nombre incrémenté servira à récupérer dans l'ordre, toutes les valeurs uniques purgées des doublons. Et pour savoir si un numéro de lot a déjà été recensé, nous devons exploiter la fonction Excel NB.SI dans la zone de critère d'une fonction SI.

• Cliquer sur l'onglet Stock en bas de la fenêtre Excel pour activer sa feuille,
• Sélectionner la cellule G3 et taper le symbole = pour débuter le calcul,
• Saisir le nom de la fonction conditionnelle suivi d'une parenthèse, soit Si(,
• Saisir la fonction de dénombrement conditionnel suivi d'une parenthèse, soit Nb.Si(,
• Cliquer sur la cellule C2 pour désigner le point de départ de la plage de cellules,
• Taper le symbole deux points (:) pour générer la plage : C2:C2,
• Figer la première des deux références à l'aide de la touche F4 du clavier, soit : $C$2:C2,
• Taper un point-virgule (;) pour passer dans l'argument du critère à dénombrer,
• Sélectionner le premier numéro de lot, soit la cellule C3,
• Fermer la parenthèse de la fonction Nb.Si,
• Taper le symbole Supérieur suivi du chiffre 0, soit >0,

Nous cherchons ainsi à savoir si lenuméro de lot pour l'enregistrement en cours a déjà été comptabilisé.

• Taper un point-virgule (;) pour passer dans la branche Alors de la fonction Si,
• Saisir deux guillemets ('') pour garder la cellule vide lorsque le lot a déjà été référencé,
• Taper un nouveau point-virgule (;) pour passer dans la branche Sinon de la fonction Si,
• Saisir le nom de la fonction pour indiquer la plus grande valeur, suivi d'une parenthèse, soit Max(,
• Sélectionner la première cellule de la plage du décompte en cours, soit G2,
• Taper la symbole deux points (:) pour générer la plage G2:G2,
• Figer la première des deux références, soit $G$2:G2,
• Fermer la parenthèse de la fonction Max,
• Ajouter une unité à ce résultat statistique, soit + 1,
• Fermer la parenthèse de la fonction Si et valider la formule par le raccourci CTRL + Entrée,
• Double cliquer sur la poignée de la cellule pour reproduire le calcul sur la hauteur du tableau,

La formule que nous avons bâtie est la suivante :

=SI(NB.SI($C$2:C2; C3)>0; ''; MAX($G$2:G2) + 1)

Sur une plage évoluant en même temps que le calcul est répliqué ($C$2:C2), nous cherchons à savoir si le numéro de lot (C3) a déjà été trouvé (>0). Lorsque ce n'est pas le cas, dans la colonne en cours, elle aussi évolutive, nous affectons un numéro incrémenté (MAX($G$2:G2) + 1). Ainsi, nous identifions par une valeur unique, chaque numéro de lot non redondant. Nous exploiterons ensuite ces marqueurs numériques pour extraire ces références purgées de leurs doublons, afin de construire la liste déroulante.



Comme l'illustre la capture ci-dessus, un numéro unique vient référencer un numéro de lot, dans la mesure où il n'a pas déjà été identifié. D'ailleurs, la mise en forme conditionnelle prédéfinie sur ce tableau trié croissant sur les références, en atteste.

Nous proposons désormais d'importer ces références uniques dans une plage de cellules arbitraires de la feuille Console. Nous allons exploiter les fonctions de base de données Index et Equiv, pour retourner chaque valeur en fonction de son indice de ligne et de son indice de colonne. L'indice de colonne est déjà connu puisque le numéro de lot se situe en colonne C, soit en deuxième colonne (2) de la base de données. L'indice de ligne quant à lui est variable. Il dépend de ces numéros incrémentés qu'il faut tous trouver tour à tour. C'est la fonction Excel Ligne que nous avons déjà exploitée pour les mêmes objectifs, qui va permettre de faire glisser le chiffre à trouver.

• Cliquer sur l'onglet Console en bas de la fenêtre Excel pour activer sa feuille,
• Sélectionner la cellule M4 et taper le symbole = pour débuter le calcul,
• Saisir le nom de la fonction de gestion d'erreur suivi d'une parenthèse, soit =sierreur(,
• Saisir le nom de la fonction d'extraction de base de données suivi d'une parenthèse, soit index(,
• Cliquer alors sur l'onglet Stock en bas de la fenêtre Excel pour activer sa feuille,
• Sélectionner les colonnes B à F de la base de données, soit Stock!B:F,
• Taper un point-virgule (;) pour passer dans l'argument du numéro de ligne,
• Saisir la fonction retournant l'indice de ligne suivi d'une parenthèse, soit equiv(,
• Saisir la fonction renvoyant la ligne d'une cellule suivi d'une parenthèse, soit ligne(,
• Cliquer sur l'onglet Console en bas de la fenêtre Excel pour activer sa feuille,
• Sélectionner une cellule sur la première ligne de la feuille, par exemple M1,

De fait, en répliquant le calcul sur les lignes du dessous, la formule désignera les numéros incrémentés tour à tour, en déplaçant la référence de la cellule ainsi désignée.

• Fermer la parenthèse de la fonction Ligne,
• Taper un point-virgule (;) pour passer dans l'argument de la colonne de recherche,
• Cliquer sur l'onglet Stock en bas de la fenêtre Excel pour activer sa feuille,
• Désigner la colonne G des numéros incrémentés, soit Stock!G:G,
• Taper un point-virgule suivi du chiffre 0 pour demander une correspondance exacte,
• Puis, fermer la parenthèse de la fonction Equiv,

A ce stade, la fonction Equiv est censée avoir retourné le numéro de ligne du chiffre recherché. Il ne reste plus qu'à indiquer le numéro de colonne pour que la fonction Index retourne la valeur située au croisement des deux.

• Taper un point-virgule pour passer dans l'argument du numéro de colonne de la fonction Index,
• Saisir le chiffre 2 pour indiquer la deuxième colonne de la sélection,
• Fermer la parenthèse de la fonction Index,
• Taper un point-virgule pour passer dans le second argument de la fonction SiErreur,
• Saisir deux guillemets ('') pour conserver la cellule vide lorsque la recherche est infructueuse,
• Fermer la parenthèse de la fonction SiErreur,
• Valider le calcul par CTRL + Entrée,
• Tirer la poignée de la cellule jusqu'à la ligne 400 par exemple pour extraire toutes les références uniques,

La formule que nous avons bâtie est la suivante :

=SIERREUR(INDEX(Stock!B:F; EQUIV(LIGNE(M1); Stock!G:G;0); 2); '')

La fonction SiErreur est exploitée comme un garde-fou. Elle permet d'intercepter les messages d'erreurs retournés par les fonctions d'extraction, lorsque la recherche échoue. La fonction Index initie ensuite la recherche dans le tableau de base de données, situé entre les colonnes B et F. En désignant l'intégralité des colonnes, nous construisons un calcul dynamique qui sera capable d'intégrer les nouveaux enregistrements, si la base de données venait à évoluer. La fonction Equiv se charge ensuite de retourner l'indice de ligne de la référence à extraire. Pour cela, elle réalise la recherche du numéro incrémenté, en partant de la valeur 1 (LIGNE(M1)), dans la colonne G. L'indice de colonne qui est fourni en dernier paramètre, suffit alors à compléter la référence manquante, pour l'extraction de la donnée contenue dans la cellule, ainsi désignée dynamiquement.



Finalement, comme l'illustre la capture ci-dessus, nous arrivons bien à reconstruire la liste des numéros de lots, sans les répétitions. Souvenez-vous, la référence D95831 est marquée comme doublon à de nombreuses reprises par le format conditionnel, dans la feuille Stock de la base de données. Mais dans la liste restituée, elle n'apparaît bien qu'une seule fois.

Liste déroulante dynamique
Dans le souci d'une application professionnelle et évolutive, nous partons du principe que la base de données est en perpétuelle évolution. En conséquence, la liste des références purgée de ses doublons est susceptible d'évoluer en nombre de lignes. Notre souci est de bâtir une liste déroulante dynamique dont la plage s'adapte aux nombres de cellules proposées. Pour cela, nous devons faire varier la hauteur de cette plage grâce à la fonction Excel Decaler. Et pour connaître cette hauteur, dans la colonne N, nous proposons préalablement de marquer chaque référence effectivement inscrite par un indicateur numérique.

• Dans la cellule N4 de la feuille Console, saisir la formule Excel suivante :

=SI(M4<>''; 1; '')

• Double cliquer sur la poignée de la cellule pour répliquer le calcul,

Lorsque la référence est effectivement inscrite, nous ajoutons la valeur numérique 1 dans la cellule, et rien dans le cas contraire. Comme la fonction NB est capable de compter le nombre de valeurs numériques dans une colonne, elle est capable de retourner la hauteur de la plage à considérer.

• Sélectionner désormais la cellule B5 de la feuille Console,
• Cliquer sur l'onglet Données en haut de la fenêtre Excel pour activer son ruban,
• Dans la section Outils de données du ruban, cliquer sur le bouton Validation de données,
• Dans la zone Autoriser de la boîte de dialogue qui suit, choisir Liste,
• Puis cliquer dans la zone Source située juste en-dessous pour l'activer,
• Taper le symbole = pour débuter la formule consistant à définir les bornes de la plage,
• Saisir la fonction pour adapter les plages suivi d'une parenthèse, soit decaler(,
• Cliquer sur la cellule de départ de la plage de données source, soit $M$4,
• Puis saisir un point-virgule suivi du chiffre 0 (;0),
• Saisir de nouveau un point-virgule suivi du chiffre 0 (;0),

Les deux arguments que nous venons de renseigner concernent les décalages éventuels à réaliser par rapport à la cellule de départ, désignée en premier argument. Nous ne souhaitons aucun décalage. Nous souhaitons seulement faire varier la borne inférieure de la plage de cellules, en fonction du nombre de données présentes. Justement, l'argument qui suit permet de définir cette hauteur.

• Taper un point-virgule pour passer dans l'argument de la hauteur de la fonction Decaler,
• Saisir le nom de la fonction de dénombrement numérique suivi d'une parenthèse, soit NB(,
• Cliquer sur l'étiquette de colonne N pour indiquer où réaliser le décompte,
• Fermer la parenthèse de la fonction Nb puis fermer la parenthèse de la fonction Decaler,
• Valider cette construction dynamique en cliquant sur le bouton Ok de la boîte de dialogue,
• Cliquer sur la flèche de la liste déroulante en B5,

Comme vous le constatez, la taille de la liste déroulante est parfaitement adaptée à la hauteur des données importées sans doublons, par calcul Excel. La formule que nous avons bâtie pour ajuster le contenu de la liste déroulante à la taille des données, est la suivante :

=DECALER($M$4; 0; 0; NB($N:$N))

Repérer tous les enregistrements d'une même référence
Maintenant que nous connaissons la valeur choisie par l'utilisateur, nous devons débuter les calculs permettant de repérer les enregistrements correspondants dans la base de données. Ces repères permettront de réaliser plus simplement l'extraction de toutes les lignes concordantes.

Le raisonnement est l'inverse du précédent. Cette fois, nous ne souhaitons pas marquer les références uniques. Justement, nous souhaitons repérer tous les enregistrements dépendant d'un même numéro de lot, soit tous les doublons.

• Cliquer sur l'onglet Stock en bas de la fenêtre Excel pour activer sa feuille,
• Sélectionner la cellule H3 et taper le symbole = pour débuter le calcul,
• Saisir le nom de la fonction conditionnelle suivi d'une parenthèse, soit =SI(,
• Sélectionner le premier numéro de lot à comparer, soit la cellule C3,
• Taper le symbole = pour l'égalité du critère à vérifier,
• Cliquer sur l'onglet Console en bas de la fenêtre Excel pour activer sa feuille,
• Sélectionner alors la cellule de la liste déroulante en la figeant, ou saisir ses références, soit Console!$B$5,
• Taper un point-virgule pour passer dans la branche Alors de la fonction Si,
• Saisir le nom de la fonction pour calculer le plus grand nombre sur une plage, suivi d'une parenthèse, soit MAX(,
• Sélectionner la première cellule de la plage de calcul en cours, soit H2,
• Taper le symbole deux points (:) pour générer la plage H2:H2,
• Figer la borne supérieure de la plage avec la touche F4, soit $H$2:H2,
• Fermer la parenthèse de la fonction Max,
• Puis, incrémenter le calcul d'une unité, soit +1,
• Taper un point-virgule pour passer dans la branche Sinon de la fonction Si,
• Saisir deux guillemets ('') pour garder la cellule vide lorsque la référence ne correspond pas,
• Fermer la parenthèse de la fonction Si,
• Valider le calcul par le raccourci CTRL + Entrée,
• Enfin, double cliquer sur la poignée de la cellule pour le répliquer sur la hauteur du tableau,

Dans l'exemple de la capture ci-dessus, pour la référence D95831 sélectionnée depuis la feuille Console, tous les lots portant ce code, sont marqués sans exception avec un numéro incrémenté. Il suffira donc d'exploiter la même technique que précédemment en imbriquant les fonctions d'extraction Index et Equiv, sur la base d'un numéro de ligne évoluant, grâce à la fonction Excel Ligne.

La formule que nous avons bâtie est la suivante :

=SI(C3=Console!$B$5; MAX($H$2:H2) + 1; '')

Si le numéro de lot (C3) est identique au choix de l'utilisateur (Console!$B$5), alors nous le repérons à l'aide d'un numéro incrémenté (MAX($H$2:H2)+1), tant qu'il est répété. Puisque nous devons réaliser des extractions croisées en rapatriant notamment, les ordres de fabrication (OF) correspondant à ce numéro de lot, nous proposons de répliquer ce calcul, sur la feuille OF.

• Cliquer sur l'onglet OF en bas de la fenêtre Excel pour activer sa feuille,
• En cellule X2, construire la formule suivante :

=SI(S2=Console!$B$5; MAX($X$1:X1) + 1; '')

• Valider le calcul par le raccourci CTRL + Entrée,
• Le répliquer sur la hauteur de la base de données en double cliquant sur la poignée de la cellule,

Le principe est exactement le même que précédemment, en adaptant les références des colonnes à la source de données. Nous souhaitons vérifier l'équivalence entre les numéros de lot qui sont énumérés en colonne S cette fois. Chaque doublon est repéré par un numéro incrémenté (MAX($X$1:X1)+1). Si bien que nous pourrons remonter à chacun de ces enregistrements pour en extraire le détail, dont les ordres de fabrication.

Importer toutes les lignes d'une seule référence
Il est temps d'exploiter les fonctions d'extraction sur la base de la recherche d'un indice de ligne incrémenté, en commençant par le code article en cellule C5. Il s'agira ensuite de répliquer cette même logique en adaptant le numéro de colonne d'extraction pour la feuille Stock et les références des champs pour la feuille OF.

• Sélectionner la cellule C5 de la feuille Console,
• Taper le symbole = pour débuter le calcul,
• Saisir le nom de la fonction de gestion d'erreur suivi d'une parenthèse, soit =SIERREUR(,
• Saisir la fonction d'extraction par indice de ligne et de colonne suivi d'une parenthèse, soit INDEX(,
• Cliquer sur l'onglet Stock en bas de la fenêtre Excel pour activer sa feuille,
• Sélectionner les colonnes de la base par leurs étiquettes, soit Stock!B:F,
• Taper un point-virgule pour passer dans l'argument de l'indice de ligne à fournir,
• Saisir la fonction retournant un numéro de ligne suivi d'une parenthèse, soit EQUIV(,
• Saisir la fonction retournant l'indice de ligne d'une cellule suivi d'une parenthèse, soit LIGNE(,
• Cliquer sur l'onglet Console en bas de la fenêtre Excel pour activer sa feuille,
• Sélectionner la cellule A1,
• Fermer la parenthèse de la fonction Ligne,
• Taper un point-virgule pour passer dans l'argument de la colonne de recherche,
• Cliquer sur l'onglet Stock en bas de la fenêtre Excel pour activer sa feuille,
• Désigner la colonne H par son étiquette, ce qui donne : Stock!H:H,
• Taper un point-virgule suivi du chiffre 0 (;0) pour demander une correspondance exacte,
• Fermer la parenthèse de la fonction Equiv,
• Taper un point-virgule pour passer dans l'argument de l'indice de colonne de l'information à extraire,
• Saisir le chiffre 1 pour indiquer la première colonne de la base de données, celle du code article,
• Fermer la parenthèse de la fonction Index,
• Taper un point-virgule pour passer dans le second argument de la fonction SiErreur,
• Saisir deux guillemets ('') pour garder la cellule vide lorsque le numéro de lot ne correspond pas,
• Fermer la parenthèse de la fonction SiErreur et valider la formule,

Un code article unique est associé à une référence de lot. Il n'est donc pas prévu de répliquer ce calcul dans ce cas. Mais nous l'avons néanmoins bâti dans cette philosophie pour extraire toutes les données déclinées comme la quantité en Kg et l'emplacement. La formule complète que nous avons construite est la suivante :

=SIERREUR(INDEX(Stock!B:F; EQUIV(LIGNE(A1); Stock!H:H; 0); 1); '')

Par exemple, pour le numéro de lot D95831 prédéfini, nous obtenons en retour la référence 104903 qui est bien le code article correspondant. Il ne reste plus qu'à répliquer ce calcul en cellules B7, B10 et C10 pour respectivement extraire la désignation correspondante puis, toutes les quantités et emplacements associés, par réplication. L'information à adapter est l'indice de colonne afin de le faire correspondre au numéro de champ de l'information à récupérer. Pour la description, il s'agit de la troisième colonne (3). Pour la quantité et l'emplacement, il s'agit respectivement des colonnes 4 et 5.

• En cellule B7, adapter le calcul comme suit :

=SIERREUR(INDEX(Stock!B:F; EQUIV(LIGNE(A1); Stock!H:H; 0); 3);'')

• En cellules B10 et C10, adapter la formule respectivement comme suit :

=SIERREUR(INDEX(Stock!B:F; EQUIV(LIGNE(A1); Stock!H:H; 0); 4); '')
=SIERREUR(INDEX(Stock!B:F; EQUIV(LIGNE(A1); Stock!H:H; 0); 5); '')

• Tirer la poignée des cellules B10 et C10 sur plusieurs dizaines de lignes vers le bas

Le défi semble d'ores et déjà relevé. Nous avons en effet réussi à importer tous les enregistrements correspondant à une référence unique, par le biais de calculs intermédiaires d'incrémentations et grâce aux fonctions Excel d'extraction, Index et Equiv. Néanmoins, il reste à adapter ces calculs de manière à importer toutes les données attachées, issues de la source liée, située dans la feuille OF.

• En cellule E5 de la feuille console, construire la formule d'extraction suivante :

=SIERREUR(INDEX(OF!A:W; EQUIV(LIGNE(A1); OF!X:X; 0); 6); '')

• Puis en F5, adapter le calcul en modifiant l'indice de colonne, comme suit

=SIERREUR(INDEX(OF!A:W; EQUIV(LIGNE(A1); OF!X:X; 0); 1); '')

• De G5 à K5, reproduire le calcul en adaptant respectivement l'indice de colonne pour la donnée à extraire :

=SIERREUR(INDEX(OF!A:W; EQUIV(LIGNE(A1); OF!X:X; 0); 4); '')
=SIERREUR(INDEX(OF!A:W; EQUIV(LIGNE(A1); OF!X:X; 0); 8); '')
=SIERREUR(INDEX(OF!A:W; EQUIV(LIGNE(A1); OF!X:X;0); 13); '')
=SIERREUR(INDEX(OF!A:W; EQUIV(LIGNE(A1); OF!X:X;0); 14); '')
=SIERREUR(INDEX(OF!A:W; EQUIV(LIGNE(A1); OF!X:X;0); 23); '')

• Sélectionner ensuite la plage de cellules E5:K5,
• Puis, tirer la poignée de la sélection sur plusieurs dizaines de lignes vers le bas,

Ainsi, en fonction du détail associé à chaque numéro de lot, nous prévoyons suffisamment de lignes de calculs, pour produire l'extraction de toutes les informations qui lui sont associées.

• A l'aide de la liste déroulante en B5, sélectionner le numéro de lot G03472,

Instantanément, toutes les informations attachées au numéro de lot répété, sont importées dans la feuille Console, grâce uniquement aux calculs Excel.



Il s'agit d'un outil logistique précieux pour le responsable d'équipe, qui récupère toutes les données croisées, issues de plusieurs sources, en un seul clic. Il peut vérifier l'état en cours des ordres de fabrication ainsi que la cohérence des quantités exprimées en Kilos, entre les informations situées dans la première table, et celles situées dans la source qui lui est liée. Pour parfaire l'application, il convient de masquer les colonnes de calculs intermédiaires.

• Masquer les colonnes M et N de la feuille Console,
• Masquer les colonnes G et H de la feuille Stock,
• Masquer la colonne X de la feuille OF,

Dans une prochaine formation, nous proposerons d'enrichir ces résultats d'extractions par des calculs statistiques dynamiques, qui permettront de renforcer la clarté de l'information et la facilité d'interprétation des données.

Dernière remarque, vous avez pu constater une fois encore, l'apparition de bordures d'encadrement automatiques, sur les données extraites. Il s'agit comme précédemment d'une mise en forme conditionnelle consistant à déclencher dynamiquement un tracé d'encadrement sur une plage, à partir du moment où le contenu de la cellule est détecté comme non vide.