Adapter dynamiquement la vue d'un graphique Excel

Pour partager cette vidéo sur les réseaux sociaux ou sur un site, voici son url :


Sujets que vous pourriez aussi aimer :


Adapter automatiquement le graphique

Une liste déroulante pour choisir la période à représenter graphiquement, voilà l'enjeu que propose cette formation.



Nos travaux portent sur un tableau résumant les ventes réalisées par chacun des commerciaux de l'entreprise. Au choix d'un mois par le biais d'une liste déroulante, la représentation graphique s'ajuste pour livrer le rendu visuel correspondant à la demande. Ainsi, les résultats de chacun peuvent être confrontés facilement sur une période choisie.

Source et présentation
Pour développer cette solution, nous souhaitons débuter à partir d'un tableau existant.

• Télécharger le classeur graphique-ajuste-dynamiquement.xlsx en cliquant sur ce lien,
• Double cliquer sur le fichier réceptionné pour l'ouvrir dans Excel,
• Puis, cliquer sur le bouton Activer la modification du bandeau de sécurité,

Nous trouvons donc le tableau synthétisant les ventes réalisées par les commerciaux, du mois de Janvier au mois de Juin. Une représentation graphique est déjà proposée.

• Sur le graphique, cliquer sur l'une des barres de données,

C'est ainsi l'ensemble de la série qui est sélectionnée. En consultant la barre de formule, nous visualisons sa syntaxe de construction :

=SERIE(Ventes!$D$5; Ventes!$B$6:$B$13; Ventes!$D$6:$D$13; 1)

Il s'agit donc d'un graphique statique construit arbitrairement sur le mois de Février. Le titre est puisé à partir de la cellule D5 (Ventes!$D$5). Les vendeurs sont placés sur l'axe des abscisses (Ventes!$B$6:$B$13). Enfin, les données numériques, donc les ventes, sont représentées par la partie variable, celle du mois à choisir (Ventes!$D$6:$D$13). Ici elle est fixée et c'est elle que nous devons rendre dynamique, selon le choix émis par l'utilisateur. Et à ce sujet, vous notez la présence d'une liste déroulante en cellule K3. Elle offre de désigner l'un des six mois du tableau.

Plage de cellules variable
Pour que le graphique ajuste sa représentation sur le mois choisi par l'utilisateur, l'astuce consiste premièrement à créer une plage de cellules variable. En exploitant la fonction Excel Decaler, celle-ci doit permettre de pointer sur la colonne correspondant au mois défini. Ainsi et ensuite, nous n'aurons plus qu'à exploiter ce nom pour ajuster la source de données du graphique.

• En haut de la fenêtre Excel, cliquer sur l'onglet Formules pour activer son ruban,
• Dans la section Noms définis du ruban, cliquer sur le bouton Gestionnaire de noms,
• Dans le gestionnaire qui apparaît, cliquer sur le bouton Nouveau,
• Dans la boîte de dialogue qui suit, saisir le nom : Periode,
• Supprimer le contenu de la zone Fait référence à,
• Puis, taper le symbole égal (=) pour initier la nouvelle syntaxe,
• Inscrire la fonction d'ajustement suivie d'une parenthèse, soit : Decaler(,
• Désigner la première des ventes en cliquant sur sa cellule C6, ce qui donne : Ventes!$C$6,

Ainsi, nous définissons arbitrairement le point de départ de la plage des ventes à représenter. Ce point de référence est appelé à évoluer au choix du mois par l'utilisateur. Il doit donc subir un décalage en colonne pour pointer sur la bonne rangée à schématiser.

• Taper deux points-virgules, soit : ;;, pour ignorer l'argument du décalage en ligne,

De fait, nous nous retrouvons dans l'argument du décalage en colonne. Pour pointer sur la bonne rangée, nous devons chercher la position du mois choisi dans la ligne de titre du tableau. Pour cela, nous avons besoin de la fonction Excel Equiv.

• Inscrire le nom de la fonction suivi d'une parenthèse, soit : Equiv(,
• Désigner le mois choisi en cliquant sur sa cellule K3, ce qui donne : Ventes!$K$3,

Ainsi, nous définissons la valeur du mois à chercher.

• Taper un point-virgule (;) pour passer dans l'argument de la colonne de recherche,
• Sélectionner la ligne des mois dans le tableau, ce qui donne : Ventes!$C$5:$H$5,
• Taper un point-virgule suivi du chiffre zéro, soit : ;0, pour réaliser une recherche exacte,
• Fermer la parenthèse de la fonction Equiv,
• Puis, retrancher une unité à ce résultat, soit : -1,
• Taper un point-virgule (;) pour passer dans l'argument de la hauteur de la plage,

Ici, nous la considérons comme fixée. 8 ventes composent chaque colonne. Dans les formations à venir, nous la considèrerons comme variable pour permettre au tableau de s'enrichir et donc à sa représentation graphique de s'adapter.

• Saisir le chiffre 8 et fermer la parenthèse de la fonction Decaler,

La syntaxe complète est donc la suivante :

=Decaler(Ventes!$C$6; ; Equiv(Ventes!$K$3; Ventes!$C$5:$H$5; 0)-1; 8)

• Cliquer sur le bouton Ok de la boîte de dialogue,
• De retour sur le gestionnaire de noms, cliquer sur le bouton Fermer,

De fait, nous sommes de retour sur la feuille Excel.

Série de données dynamique
Nous devons désormais exploiter cette plage variable et ajustée au choix de l'utilisateur. Elle doit permettre à la série de données de s'adapter pour représenter les ventes du mois sélectionné.

• Cliquer sur l'une des barres du graphique pour sélectionner toute la série,
• Dans la barre de formule, remplacer le premier argument Ventes!$D$5 en cliquant sur K3,

La syntaxe résultante est la suivante : Ventes!$K$3. Il s'agit du titre du graphique. Nous l'adaptons au choix émis par l'utilisateur par le biais de la liste déroulante.

L'avant dernier argument (Ventes!$D$6:$D$13) concerne la représentation graphique des ventes. C'est là que nous devons exploiter notre plage nommée. Mais attention, une contrainte existe. Elle doit être préfixée du nom du classeur entre simples côtes.

• Remplacer cet avant dernier argument comme suit :

'graphique-ajuste-dynamiquement.xlsx'!Periode

Attention, un point d'exclamation est nécessaire entre le nom du classeur et le nom de la plage de cellules.



Désormais, à chaque changement de mois par le biais de la liste déroulante, le graphique s'adapte pour représenter les ventes concernées.